Contenido

# Función Format

Convierte una expresión numérica en una cadena y, a continuación, le da el formato que se especifique.

### Sintaxis:

    Format(expresión [, formato As String]) As String

### Parámetros:

expresión: la expresión numérica que quiere convertir en una cadena formateada.

format: String that specifies the format code for the number. If format is omitted, the Format function works like the LibreOffice Basic Str() function.

### Return type:

Cadena de texto.

## Códigos de formato

In BASIC, a format code can be divided into three sections that are separated by semicolons. The first part defines the format for positive values, the second part for negative values, and the third part for zero. If you only specify one format code, it applies to all numbers.

Puede definir el formato regional de los números, las fechas y las monedas en LibreOffice BASIC al dirigirse a LibreOffice ▸ PreferenciasHerramientas ▸ Opciones ▸ Idiomas y regiones ▸ Generales. En los códigos de formato de BASIC, el punto decimal (.) se utiliza siempre como sustitutivo del separador decimal definido en la configuración regional elegida; este punto se reemplazará por el carácter correspondiente.

Lo mismo se aplica a los valores de configuración de los formatos de fecha, hora y moneda. El código de formato de Basic se interpretará y se mostrará según los valores de configuración del entorno local correspondientes.

La lista siguiente describe los códigos que puede utilizar para dar formato a una expresión numérica:

Código | Descripción
--- | ---
0 | If expression has a digit at the position of the 0 in the format code, the digit is displayed, otherwise a zero is displayed. If expression has fewer digits than the number of zeros in the format code, (on either side of the decimal), leading or trailing zeros are displayed. If the expression has more digits to the left of the decimal separator than the amount of zeros in the format code, the additional digits are displayed without formatting. Decimal places in the expression are rounded according to the number of zeros that appear after the decimal separator in the format code.
# | If expression contains a digit at the position of the # placeholder in the format code, the digit is displayed, otherwise nothing is displayed at this position. This symbol works like the 0, except that leading or trailing zeroes are not displayed if there are more # characters in the format code than digits in the expression. Only the relevant digits of the expression are displayed.
. (period) | El sustitutivo decimal determina el número de decimales a la izquierda y a la derecha del separador decimal. If the format code contains only # placeholders to the left of this symbol, numbers less than 1 begin with a decimal separator. To always display a leading zero with fractional numbers, use 0 as a placeholder for the first digit to the left of the decimal separator. El uso del punto como separador de millares y decimales depende de la configuración regional. Cuando introduzca un número directamente en el código fuente BASIC, utilice siempre el punto como delimitador decimal. El carácter que se muestra como separador decimal depende del formato numérico de la configuración del sistema.
% | Multiplies the expressionby 100 and inserts the percent sign (%) where the expression appears in the format code.
E- E+ e- e+ | If the format code contains at least one digit placeholder (0 or #) to the right of the symbol E-, E+, e-, or e+, the expression is formatted in the scientific or exponential format. The letter E or e is inserted between the number and the exponent. The number of placeholders for digits to the right of the symbol determines the number of digits in the exponent. Si el exponente es negativo, se muestra un signo menos justo antes de un exponente con E-, E+, e-, e+. Si el exponente es positivo, sólo se muestra un signo más antes de exponentes con E+ o e+.
- + $ ( ) space | : A plus (+), minus (-), dollar ($), space, or brackets entered directly in the format code is displayed as a literal character.
\ | Para que se muestren caracteres distintos de los que se indican aquí, es necesario colocarles una contrabarra (\) antes o entrecomillarlos (" "). The backslash displays the next character in the format code. Characters in the format code that have a special meaning can only be displayed as literal characters if they are preceded by a backslash. The backslash itself is not displayed, unless you enter a double backslash (\\) in the format code. Los caracteres que deben precederse por una barra oblicua inversa en el código de formato para que se muestren como caracteres literales son: caracteres de formato de hora y fecha (a, c, d, h, m, n, p, q, s, t, w, y, /, :), caracteres de formato numérico (#, 0, %, E, e, coma, punto) y caracteres de formato de cadena (@, &, <, >, !).

## Formatos predefinidos

You can also use the following predefined number formats. Except for "General Number", all of the predefined format codes return the number as a decimal number with two decimal places.

Si se usan formatos predefinidos, el nombre del formato debe entrecomillarse.

Código | Descripción
--- | ---
"<" | Convert expression to lower case
">" | Convert expression to upper case.
"c" or "General Date" | Returns the numeric expression in short date format, optionally with "H:MM:SS AM/PM". If expression is a string, returns the string.
"n" | Returns the minute of the numeric expression, with 1 or 2 digits.
"nn" | Returns the minute of the numeric expression with two digits.
"w" | Returns the week day of the numeric expression. 1 is Sunday and 7 is Saturday.
"General Number" | Returns the numeric expression with 12 digits (0.############).
"Currency" | Devuelve la expresión numérica en la moneda de la configuración regional.
"Fixed" | Returns the numeric expression with 2 decimal places (0.00).
"Standard" | Returns the numeric expression with thousands separators and 2 decimals (@0.00).
"Percent" | Returns the numeric expression as percent value (0.00%).
"Scientific" | Returns the numeric expression in scientific notation (#.00E+00);
"Yes/No" | Returns "Yes" if the numeric expression is not equal to zero, "No" otherwise. "Yes" and "No" are localized.
"True/False" | Returns "True" if the numeric expression is not equal to zero, "False" otherwise. "True" and "False" are localized.
"On/Off" | Returns "On" if the numeric expression is not equal to zero, "Off" otherwise. "On" and "Off" are localized.
"Long Date" or "dddddd" | Devuelve la expresión numérica en el formato de fecha largo del sistema, que depende de la configuración regional.
"Medium Date" | Devuelve la expresión numérica en formato de fecha DD-MMM-AA, que depende de la configuración regional.
"Short Date" or "ddddd" | Devuelve la expresión numérica en el formato de fecha corto del sistema, que depende de la configuración regional.
"Long Time" or "ttttt" | Devuelve la expresión numérica en el formato de hora largo del sistema, que depende de la configuración regional («H:MM:SS AM/PM»).
"Medium Time" | Returns the numeric expression in system medium time format, and depends on the locale (HH:MM AM/PM)
"Short Time" | Devuelve la expresión numérica en el formato de hora corto del sistema, que depende de la configuración regional (HH:MM).

### Códigos de error:

5 Llamada a procedimiento no válida

### Ejemplo:

    Sub ExampleFormat
        MsgBox Format(6328.2, "##,##0.00")
        ' utilice siempre el punto como delimitador de decimales al introducir números en el código fuente de Basic.
        ' por ejemplo, muestra 6,328.20 en entorno local inglés y 6.328,20 en entorno local alemán.
    msgbox Format("ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890", "<") ' returns abcdefghijklmnopqrstuvwxyz1234567890, digits not affected.
    msgbox Format("abcdefghijklmnopqrstuvwxyz1234567890", ">") ' devuelve ABCDEFGHIJKLMNOPQRSTUVWXYZ1234567890; las cifras no se modifican.
    msgBox Format(12345.6,"c") ' returns the number in date format as 18/10/33 2:24:00 PM in German locale.
    msgBox Format(12345.6,"General Date") ' Same as "c".
    msgbox format(12345.004,"n") ' returns 5
    msgbox format(12345.004,"nn") ' returns 05
    msgbox format(12345.6,"w") ' returns 4 (Wednesday).
    msgbox format(log(123),"General Number") ' returns 4,812184355372 in German locale
    msgbox format(123456.7890,"Fixed") ' 123456.79
    msgbox format(123456.1234,"Fixed") ' 123456.12
    msgbox format(123456.7890,"Standard") '123,456.79
    msgbox format(123456.1234,"Standard") '123,456.12
    msgbox format(12.3456,"Percent") ' 1234.56%
    msgbox format(0.123456,"Percent") '12.35%
    msgbox format(123,"Yes/No") ' returns localized "Yes"
    msgbox format(0,"Yes/No") ' returns localized "No"
    msgbox format(-1,"True/False") ' returns localized "True"
    msgbox format(123,"On/Off") ' returns localized "On"
    msgbox format(45756.73,"Long Date") ' returns Wednesday, April 9, 2025 in your locale
    End Sub

Temas relacionados

Códigos de formatos numéricos

Funciones de cadenas