Справка Scilab >> Data Structures > cell

cell

создаёт cell-массив пустых матриц

Последовательность вызова

c = cell()
c = cell(m1)
c = cell(m1, m2)
c = cell(m1, m2, ..., mn)
c = cell(x)

Аргументы

x: целочисленный вектор, содержащий размеры cell-массива, который требуется создать.
m1, m2, ..., mn: целые числа: размеры cell-массива, который требуется создать.

Описание

Функция cell возвращает cell-массив пустых матриц.

cell(): возвращает cell-массив размером 0 x 0 пустых матриц.
cell(m1): возвращает cell-массив размером m1 x m1) пустых матриц.
cell(m1, m2): возвращает cell-массив размером m1 x m2 пустых матриц.
cell(m1, m2, ..., mn): создаёт cell-массив размером m1 x m2 x ... x mn пустых матриц.
cell(x): возвращает cell-массив пустых матриц у которого первая размерность равна x(1), вторая размерность равна x(2) и так далее.

Примечания

У cell(x) не такой же размер, как у x.

cell() эквивалентна cell(0).

Если A является cell-массивом, то у вас есть допуск к содержимому элемента A с помощью A(m1, m2, ..., mn).entries. Инструкция A(1,1) = zeros(2,2) не допустима, правильным синтаксисом является A(1,1).entries = zeros(2,2).

Если A является cell-массивом, то вы можете получить его размеры с помощью A.dims, которое возвращает значение типа int32 и которое нельзя использовать в качестве индекса в cell-массиве. В этом случае лучше всего использовать size(A).

Примеры

a=cell(3)
b=cell(3,1)
c=cell([2,3,4])

// Определение cell-элементов
b=cell(3,1);

// Присвоение значения первому элементу b с помощью поля 'entries'
b(1).entries=1:3

// Присвоение значения второму элементу b с помощью поля 'entries'
b(2).entries='Scilab'

// Присвоение значения третьему элементу b с помощью поля 'entries'
b(3).entries=poly(1:3,'s')

// Присвоение cell-подмассивов
X=cell(3,2);
X(:,1)=b

// Выделение cell-подмассива: результатом является cell-массив
b(1)
b(1:2)

// Выделение значения cell-подмассива: результатом является массив
b(1).entries

// Размеры b в виде значения int32 (нельзя использовать в качестве индекса)
b.dims
// Размеры b в виде значения double
size(b)

Смотрите также

eye — единичная матрица
ones — матрица, составленная из единиц
zeros — матрица, составленная из нулей

Report an issue
<< boolean	Data Structures	definedfields >>