Net::SSH2(3)

NAME
Net::SSH2 - Support for the SSH 2 protocol via libssh2.

SYNOPSIS
  use Net::SSH2;

  my $ssh2 = Net::SSH2->new();

  $ssh2->connect('example.com')
    or $ssh2->die_with_error;

  $ssh2->check_hostkey('ask')
    or $ssh2->die_with_error;

  $ssh2->auth_publickey($ENV{USER}, "$ENV{HOME}/.ssh/id_rsa.pub", "$ENV{HOME}/.ssh/id_rsa")
    or $ssh2->die_with_error;

  my $chan = $ssh2->channel()
    or $ssh2->die_with_error;

  $chan->exec('ls')
    or $ssh2->die_with_error;

  print while <$chan>;

  print "EXIT CODE: ", $chan->exit_status, "\n";

  $chan->close;

  my $sftp = $ssh2->sftp()
    or $ssh2->die_with_error;;

  my $fh = $sftp->open('/etc/passwd')
    or $sftp->die_with_error;

  print while <$fh>;

DESCRIPTION
Net::SSH2 is a Perl interface to the libssh2 (<http://www.libssh2.org>) library. It supports the SSH2 protocol (there is no support for SSH1) with all of the key exchanges, ciphers, and compression of libssh2.

Even if the module can be compiled and linked against very old versions of the library, nothing below 1.5.0 should really be used (older versions were quite buggy and unreliable) and version 1.7.0 or later is recommended.

  Error handling
Unless otherwise indicated, methods return a true value on success and "undef" on failure; use the "error" method to get extended error information.

Important: methods in Net::SSH2 not backed by libssh2 functions (i.e. "check_hostkey" or SCP related methods) require libssh2 1.7.0 or later in order to set the error state. That means that after any of those methods fails, "error" would not return the real code but just some bogus result when an older version of the library is used.

  Typical usage
The typical usage order is as follows:

1.  Create the SSH2 object calling "new".

2.  Configure the session if required. For instance, enabling compression or picking some specific encryption methods.

3.  Establish the SSH connection calling the method "connect".

4.  Check the remote host public key calling "check_hostkey".

5.  Authenticate calling the required authentication methods.

6.  Call "channel" and related methods to create new bidirectional communication channels over the SSH connection.

7.  Close the connection letting the Net::SSH2 object go out of scope or calling "disconnect" explicitly.

CONSTANTS
All the constants defined in libssh2 can be imported from Net::SSH2.

For instance:

   use Net::SSH2 qw(LIBSSH2_CHANNEL_EXTENDED_DATA_MERGE
                    LIBSSH2_CHANNEL_FLUSH_ALL
                    LIBSSH2_HOSTKEY_POLICY_ASK);

Though note that most methods accept the uncommon part of the constant name as a string. For instance the following two method calls are equivalent:

    $channel->ext_data(LIBSSH2_CHANNEL_EXTENDED_DATA_MERGE);
    $channel->ext_data('merge');

Tags can be used to import the following constant subsets:

  callback channel error socket trace hash method
  disconnect policy fx fxf sftp

The tag "all" can also be used to import all of them.

METHODS

  new ( %options )
Create new Net::SSH2 object representing a SSH session.

The accepted options are as follows:

timeout
    Sets the default timeout in milliseconds. See "timeout".

trace
    Sets tracing. See "trace".

    Example:

        my $ssh2 = Net::SSH2->new(trace => -1);

    Note that tracing requires a version of libssh2 compiled with debugging support.

debug
    Enable debugging. See "debug".

compress
    Sets flag "LIBSSH2_FLAG_COMPRESS". See "flag".

sigpipe
    Sets flag "LIBSSH2_FLAG_SIGPIPE". See "flag".

  banner ( text )
Set the SSH2 banner text sent to the remote host (prepends required "SSH-2.0-").

  version
In scalar context, returns libssh2 version/patch e.g. 0.18 or "0.18.0-20071110". In list context, returns that version plus the numeric version (major, minor, and patch, each encoded as 8 bits, e.g. 0x001200 for version 0.18) and the default banner text (e.g. "SSH-2.0-libssh2_0.18.0-20071110").

  error
Returns the last error code. In list context, returns (code, error name, error string).

Note that the returned error value is only meaningful after some other method indicates an error by returning false.

  die_with_error ( [message] )
Calls "die" with the given message and the error information from the object appended.

For instance:

  $ssh2->connect("ajhkfhdklfjhklsjhd", 22)
      or $ssh2->die_with_error;
  # dies as:
  #    Unable to connect to remote host: Invalid argument (-1 LIBSSH2_ERROR_SOCKET_NONE)

  sock
Returns a reference to the underlying IO::Socket object (usually a derived class as IO::Socket::IP or IO::Socket::INET), or "undef" if not yet connected.

  trace
Calls "libssh2_trace" with supplied bitmask. In order to enable all tracing pass "-1" as follows:

    $ssh2->trace(-1);

A version of libssh2 compiled with tracing support is required.

  timeout ( timeout_ms )
Enables a global timeout (in milliseconds) which will affect every action (requires libssh2 1.2.9 or later).

By default, or if you set the timeout to zero, Net::SSH2 has no timeout.

Note that timeout errors may leave the SSH connection in an inconsistent state and further operations may fail or behave incorrectly. Actually, some methods are able to recover after a timeout error and others are not.

Don't hesitate to report any issue you encounter related to this so that it can be fixed or at least, documented!

  method ( type [, values... ] )
Sets or gets a method preference. For get, pass in the type only; to set, pass in either a list of values or a comma-separated string. Values can only be queried after the session is connected.

The following methods can be set or queried:

LIBSSH2_METHOD_KEX
    Key exchange method names. Supported values:

    diffie-hellman-group1-sha1
        Diffie-Hellman key exchange with SHA-1 as hash, and Oakley Group 2 (see RFC 2409).

    diffie-hellman-group14-sha1
        Diffie-Hellman key exchange with SHA-1 as hash, and Oakley Group 14 (see RFC 3526).

    diffie-hellman-group-exchange-sha1
        Diffie-Hellman key exchange with SHA-1 as hash, using a safe-prime/generator pair (chosen by server) of arbitrary strength (specified by client) (see IETF draft secsh-dh-group-exchange).

LIBSSH2_METHOD_HOSTKEY
    Public key algorithms. Supported values:

    ssh-dss
        Based on the Digital Signature Standard (FIPS-186-2).

    ssh-rsa
        Based on PKCS#1 (RFC 3447).

LIBSSH2_METHOD_CRYPT_CS
    Encryption algorithm from client to server. Supported algorithms:

    aes256-cbc
        AES in CBC mode, with 256-bit key.

    rijndael-cbc@lysator.liu.se
        Alias for aes256-cbc.

    aes192-cbc
        AES in CBC mode, with 192-bit key.

    aes128-cbc
        AES in CBC mode, with 128-bit key.

    blowfish-cbc
        Blowfish in CBC mode.

    arcfour
        ARCFOUR stream cipher.

    cast128-cbc
        CAST-128 in CBC mode.

    3des-cbc
        Three-key 3DES in CBC mode.

    none
        No encryption.

LIBSSH2_METHOD_CRYPT_SC
    Encryption algorithm from server to client. See the "LIBSSH2_METHOD_CRYPT_CS" entry above for supported algorithms.

LIBSSH2_METHOD_MAC_CS
    Message Authentication Code (MAC) algorithms from client to server. Supported values:

    hmac-sha1
        SHA-1 with 20-byte digest and key length.

    hmac-sha1-96
        SHA-1 with 20-byte key length and 12-byte digest length.

    hmac-md5
        MD5 with 16-byte digest and key length.

    hmac-md5-96
        MD5 with 16-byte key length and 12-byte digest length.

    hmac-ripemd160
        RIPEMD-160 algorithm with 20-byte digest length.

    hmac-ripemd160@openssh.com
        Alias for hmac-ripemd160.

    none
        No encryption.

LIBSSH2_METHOD_MAC_SC
    Message Authentication Code (MAC) algorithms from server to client. See LIBSSH2_METHOD_MAC_CS for supported algorithms.

LIBSSH2_METHOD_COMP_CS
    Compression methods from client to server. Supported values:

    zlib
        The "zlib" compression method as described in RFC 1950 and RFC 1951.

    none
        No compression

LIBSSH2_METHOD_COMP_SC
    Compression methods from server to client. See LIBSSH2_METHOD_COMP_CS for supported compression methods.

  connect ( handle | host [, port])
The argument combinations accepted are as follows:

a glob or "IO::*" object reference
    Note that tied file handles are not acceptable. The underlying libssh2 requires real file handles.

host [, port]
    In order to handle IPv6 addresses the optional module IO::Socket::IP is required.

    The port number defaults to 22.

This method used to accept a "Timeout" argument. That feature has been replaced by the constructor "timeout" option but note that it takes milliseconds instead of seconds!

  disconnect ( [description [, reason [, language]]] )
Sends a clean disconnect message to the remote server. Default values are empty strings for description and language, and "SSH_DISCONNECT_BY_APPLICATION" for the reason.

  hostname
The name of the remote host given at connect time or retrieved from the TCP layer.

  port
The port number of the remote SSH server.

  hostkey_hash ( hash type )
Returns a hash of the host key; note that the key is raw data and may contain nulls or control characters.

The type may be as follows:

LIBSSH2_HOSTKEY_HASH_MD5
    MD5 hash, 16 bytes long (requires libssh2 compiled with MD5 support).

LIBSSH2_HOSTKEY_HASH_SHA1
    SHA1 hash, 20 bytes long.

Note: in previous versions of the module this method was called "hostkey".

  remote_hostkey
Returns the public key from the remote host and its type which is one of "LIBSSH2_HOSTKEY_TYPE_RSA", "LIBSSH2_HOSTKEY_TYPE_DSS", or "LIBSSH2_HOSTKEY_TYPE_UNKNOWN".

  check_hostkey( [policy, [known_hosts_path [, comment] ] ] )
Looks for the remote host key inside the given known host file (defaults to "~/.ssh/known_hosts").

On success, this method returns the result of the call done under the hood to "Net::SSH2::KnownHost::check" (i.e. "LIBSSH2_KNOWNHOST_CHECK_MATCH", "LIBSSH2_KNOWNHOST_CHECK_FAILURE", "LIBSSH2_KNOWNHOST_CHECK_NOTFOUND" or "LIBSSH2_KNOWNHOST_CHECK_MISMATCH").

On failure it returns "undef".

The accepted policies are as follows:

LIBSSH2_HOSTKEY_POLICY_STRICT
    Only host keys already present in the known hosts file are accepted.

    This is the default policy.

LIBSSH2_HOSTKEY_POLICY_ASK
    If the host key is not present in the known hosts file, the user is asked if it should be accepted or not.

    If accepted, the key is added to the known host file with the given comment.

LIBSSH2_HOSTKEY_POLICY_TOFU
    Trust On First Use: if the host key is not present in the known hosts file, it is added there and accepted.

LIBSSH2_HOSTKEY_POLICY_ADVISORY
    The key is always accepted, but it is never saved into the known host file.

callback
    If a reference to a subroutine is given, it is called when the key is not present in the known hosts file or a different key is found. The arguments passed to the callback are the session object, the matching error ("LIBSSH2_KNOWNHOST_CHECK_FAILURE", "LIBSSH2_KNOWNHOST_CHECK_NOTFOUND" or "LIBSSH2_KNOWNHOST_CHECK_MISMATCH") and the comment.

  auth_list ( [username] )
Returns the authentication methods accepted by the server. In scalar context the methods are returned as a comma separated string.

When the server accepted an unauthenticated session for the given username, this method returns "undef" but "auth_ok" returns true.

  auth_ok
Returns true when the session is authenticated.

  auth_password ( username [, password [, callback ]] )
Authenticates using a password.

If the password has expired, if a callback code reference was given, it's called as "callback($self, $username)" and should return a password. If no callback is provided, LIBSSH2_ERROR_PASSWORD_EXPIRED is returned.

  auth_password_interact ( username [, callback])
Prompts the user for the password interactively (requires Term::ReadKey).

  auth_publickey ( username, publickey_path, privatekey_path [, passphrase ] )
Authenticate using the given private key and an optional passphrase.

When libssh2 is compiled using OpenSSL as the crypto backend, passing this method "undef" as the public key argument is acceptable (OpenSSL is able to extract the public key from the private one).

See also "Supported key formats".

  auth_publickey_frommemory ( username, publickey_blob, privatekey_blob [, passphrase ] )
Authenticate using the given public/private key and an optional passphrase. The keys must be PEM encoded (requires libssh2 1.6.0 or later with the OpenSSL backend).

  auth_hostbased ( username, publickey, privatekey, hostname, [, local username [, passphrase ]] )
Host-based authentication using an optional passphrase. The local username defaults to be the same as the remote username.

  auth_keyboard ( username, password | callback )
Authenticate using "keyboard-interactive". Takes either a password, or a callback code reference which is invoked as "callback->(self, username, name, instruction, prompt...)" (where each prompt is a hash with "text" and "echo" keys, signifying the prompt text and whether the user input should be echoed, respectively) which should return an array of responses.

If only a username is provided, the default callback will handle standard interactive responses (requires Term::ReadKey)

  auth_agent ( username )
Try to authenticate using an SSH agent (requires libssh2 1.2.3).

  auth ( ... )
This is a general, prioritizing authentication mechanism that can use any of the previous methods. You provide it some parameters and (optionally) a ranked list of methods you want considered (defaults to all). It will remove any unsupported methods or methods for which it doesn't have parameters (e.g. if you don't give it a public key, it can't use publickey or hostkey), and try the rest, returning whichever one succeeded or "undef" if they all failed. If a parameter is passed with an "undef" value, a default value will be supplied if possible.

The parameters are:

rank
    An optional ranked list of methods to try. The names should be the names of the Net::SSH2 "auth" methods, e.g. "keyboard" or "publickey", with the addition of "keyboard-auto" for automated "keyboard-interactive" and "password-interact" which prompts the user for the password interactively.

username
password
publickey
privatekey
    "privatekey" and "publickey" are file paths.

passphrase
hostname
local_username
interact
    If this option is set to a true value, interactive methods will be enabled.

fallback
    If a password is given but authentication using it fails, the module will fall back to ask the user for another password if this parameter is set to a true value.

cb_keyboard
    auth_keyboard callback.

cb_password
    auth_password callback.

For historical reasons and in order to maintain backward compatibility with older versions of the module, when the "password" argument is given, it is also used as the passphrase (and a deprecation warning generated).

In order to avoid that behaviour the "passphrase" argument must be also passed (it could be "undef"). For instance:

  $ssh2->auth(username => $user,
              privatekey => $privatekey_path,
              publickey => $publickey_path,
              password => $password,
              passphrase => undef);

This work around will be removed in a not too distant future version of the module.

  flag (key, value)
Sets the given session flag.

The currently supported flag values are:

LIBSSH2_FLAG_COMPRESS
    If set before the connection negotiation is performed, compression will be negotiated for this connection.

    Compression can also be enabled passing option "compress" to the constructor new.

LIBSSH2_FLAG_SIGPIPE
    if set, Net::SSH2/libssh2 will not attempt to block SIGPIPEs but will let them trigger from the underlying socket layer.

  keepalive_config(want_reply, interval)
Set how often keepalive messages should be sent.

"want_reply" indicates whether the keepalive messages should request a response from the server. "interval" is number of seconds that can pass without any I/O.

  keepalive_send
Send a keepalive message if needed.

On failure returns undef. On success returns how many seconds you can sleep after this call before you need to call it again.

Note that the underlying libssh2 function "libssh2_keepalive_send" can not recover from EAGAIN errors. If this method fails with such error, the SSH connection may become corrupted.

The usage of this function is discouraged.

  channel ( [type, [window size, [packet size]]] )
Creates and returns a new channel object. See Net::SSH2::Channel.

Type, if given, must be "session" (a reminiscence of an old, more generic, but never working wrapping).

  tcpip ( host, port [, shost, sport ] )
Creates a TCP connection from the remote host to the given host:port, returning a new channel.

The "shost" and "sport" arguments are merely informative and passed to the remote SSH server as the origin of the connection. They default to 127.0.0.1:22.

Note that this method does not open a new port on the local machine and forwards incoming connections to the remote side.

  listen ( port [, host [, bound port [, queue size ]]] )
Sets up a TCP listening port on the remote host. Host defaults to 0.0.0.0; if bound port is provided, it should be a scalar reference in which the bound port is returned. Queue size specifies the maximum number of queued connections allowed before the server refuses new connections.

Returns a new Net::SSH2::Listener object.

  scp_get ( remote_path [, local_path ] )
Retrieve a file with SCP. Local path defaults to basename of remote.

Alternatively, "local_path" may be an already open file handle or an IO::Handle object (e.g. IO::File, IO::Scalar).

  scp_put ( local_path [, remote_path ] )
Send a file with SCP. Remote path defaults to same as local.

Alternatively, "local_path" may be an already open file handle or a reference to a IO::Handle object (it must have a valid stat method).

  sftp
Return SecureFTP interface object (see Net::SSH2::SFTP).

Note that SFTP support in libssh2 is pretty rudimentary. You should consider using Net::SFTP::Foreign with the Net::SSH2 backend Net::SFTP::Foreign::Backend::Net_SSH2 instead.

  public_key
Return public key interface object (see Net::SSH2::PublicKey).

  known_hosts
Returns known hosts interface object (see Net::SSH2::KnownHosts).

  poll ( timeout, arrayref of hashes )
Deprecated: the poll functionality in libssh2 is deprecated and its usage disregarded. Session methods "sock" and "block_directions" can be used instead to integrate Net::SSH2 inside an external event loop.

Pass in a timeout in milliseconds and an arrayref of hashes with the following keys:

handle
    May be a Net::SSH2::Channel or Net::SSH2::Listener object, integer file descriptor, or perl file handle.

events
    Requested events. Combination of LIBSSH2_POLLFD_* constants (with the POLL prefix stripped if present), or an arrayref of the names ('in', 'hup' etc.).

revents
    Returned events. Returns a hash with the (lowercased) names of the received events ('in', 'hup', etc.) as keys with true values, and a "value" key with the integer value.

Returns undef on error, or the number of active objects.

  block_directions
Get the blocked direction after some method returns "LIBSSH2_ERROR_EAGAIN".

Returns "LIBSSH2_SESSION_BLOCK_INBOUND" or/and "LIBSSH2_SESSION_BLOCK_OUTBOUND".

  debug ( state )
Class method (affects all Net::SSH2 objects).

Pass 1 to enable, 0 to disable. Debug output is sent to "STDERR".

  blocking ( flag )
Enable or disable blocking.

A good number of the methods in "Net::SSH2"/"libssh2" can not work in non-blocking mode. Some of them may just forcibly enable blocking during its execution. A few may even corrupt the SSH session or crash the program.

The ones that can be safely called are "read" and, with some caveats, "write". See "write" in Net::SSH2::Channel.

Don't hesitate to report any bug you found in that area!

INTEROPERABILITY AND OTHER KNOWN ISSUES

  Protocol versions
The underlying "libssh2" library does support version 2 of the SSH protocol exclusively (hopefully, version 1 usage is almost extinct.)

The SFTP client implements version 3 of the SFTP protocol.

  Key formats
Private and public keys can be generated and stored using different formats and cyphers. Which ones are accepted by "Net::SSH2" depends on the libssh2 version being used and of the underlying crypto backend it was configured to use at build time (OpenSSL "libssl" or "libgcrypt").

An increasingly common problem is that OpenSSH since version 7.8 (released 2018-8-24) generates keys by default using the format RFC4716 which is not supported by the default crypto backend ("libssl").

Keys can be converted inplace to the old PEM format using ssh-keygen(1) as follows:

  $ ssh-keygen -p -m PEM -N "" -f ~/.ssh/id_rsa

On Windows, PuTTYgen (which is part of the PuTTY distribution) can be used to convert keys.

Another common issue is that in the last years OpenSSH has incorporated several new cyphers that are not supported by any version of "libssh2" yet. Currently the best option from an interoperability standpoint is probably to stick to RSA key usage.

  Security
Nowadays "libssh2" development is not thrilling; new versions (even minor ones) are being released just every two or three years. On the other hand security issues are found and reported far more frequently. That means that "Net::SSH2"/"libssh2" could be an easy attack vector.

So, Net::SSH2 should be used only in trusted environments. More specifically, using it to connect to untrusted third party computers over the Internet is probably a very bad idea!

SEE ALSO
Net::SSH2::Channel, Net::SSH2::Listener, Net::SSH2::SFTP, Net::SSH2::File, Net::SSH2::Dir.

LibSSH2 documentation at <http://www.libssh2.org>.

IETF Secure Shell (secsh) working group at <http://www.ietf.org/html.charters/secsh-charter.html>.

Net::SSH::Any and Net::SFTP::Foreign integrate nicely with Net::SSH2.

Other Perl modules related to SSH you may find interesting: Net::OpenSSH, Net::SSH::Perl, Net::OpenSSH::Parallel, Net::OpenSSH::Compat.

COPYRIGHT AND LICENSE
Copyright (C) 2005 - 2010 by David B. Robins (dbrobins@cpan.org).

Copyright (C) 2010 - 2020 by Rafael Kitover (rkitover@cpan.org).

Copyright (C) 2011 - 2020 by Salvador Fandiño (salva@cpan.org).

All rights reserved.

This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.8.0 or, at your option, any later version of Perl 5 you may have available.