import.pro Example File | QtQml 5.3

- Qt 5.3
- Qt QML
- Chapter 6: Writing an Extension Plugin
- import.pro Example File
- Qt 5.3.2 Reference Documentation

# import.pro Example File

tutorials/extending/chapter6-plugins/import/import.pro

    TEMPLATE = lib
    CONFIG += plugin
    QT += qml quick

    DESTDIR = ../Charts
    TARGET = $$qtLibraryTarget(chartsplugin)

    HEADERS += piechart.h \
               pieslice.h \
               chartsplugin.h

    SOURCES += piechart.cpp \
               pieslice.cpp \
               chartsplugin.cpp

    DESTPATH=$$[QT_INSTALL_EXAMPLES]/qml/tutorials/extending/chapter6-plugins/Charts

    target.path=$$DESTPATH
    qmldir.files=$$PWD/qmldir
    qmldir.path=$$DESTPATH
    INSTALLS += target qmldir

    OTHER_FILES += qmldir

    # Copy the qmldir file to the same folder as the plugin binary
    QMAKE_POST_LINK += $$QMAKE_COPY $$replace($$list($$quote($$PWD/qmldir) $$DESTDIR), /, $$QMAKE_DIR_SEP)