main.qml Example File | QtQuick 5.3

- Qt 5.3
- Qt Quick
- Qt Quick Demo - Photo Viewer
- main.qml Example File
- Qt 5.3.2 Reference Documentation

# main.qml Example File

demos/photoviewer/main.qml

    /****************************************************************************
    **
    ** Copyright (C) 2014 Digia Plc and/or its subsidiary(-ies).
    ** Contact: http://www.qt-project.org/legal
    **
    ** This file is part of the QtQml module of the Qt Toolkit.
    **
    ** $QT_BEGIN_LICENSE:LGPL$
    ** Commercial License Usage
    ** Licensees holding valid commercial Qt licenses may use this file in
    ** accordance with the commercial license agreement provided with the
    ** Software or, alternatively, in accordance with the terms contained in
    ** a written agreement between you and Digia.  For licensing terms and
    ** conditions see http://qt.digia.com/licensing.  For further information
    ** use the contact form at http://qt.digia.com/contact-us.
    **
    ** GNU Lesser General Public License Usage
    ** Alternatively, this file may be used under the terms of the GNU Lesser
    ** General Public License version 2.1 as published by the Free Software
    ** Foundation and appearing in the file LICENSE.LGPL included in the
    ** packaging of this file.  Please review the following information to
    ** ensure the GNU Lesser General Public License version 2.1 requirements
    ** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
    **
    ** In addition, as a special exception, Digia gives you certain additional
    ** rights.  These rights are described in the Digia Qt LGPL Exception
    ** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
    **
    ** GNU General Public License Usage
    ** Alternatively, this file may be used under the terms of the GNU
    ** General Public License version 3.0 as published by the Free Software
    ** Foundation and appearing in the file LICENSE.GPL included in the
    ** packaging of this file.  Please review the following information to
    ** ensure the GNU General Public License version 3.0 requirements will be
    ** met: http://www.gnu.org/copyleft/gpl.html.
    **
    **
    ** $QT_END_LICENSE$
    **
    ****************************************************************************/

    import QtQuick 2.2
    import QtQuick.Controls 1.1
    import QtQml.Models 2.1
    import "PhotoViewerCore"

    ApplicationWindow {
        id: mainWindow

        visible: true

        Rectangle {
            focus: true

            Keys.onBackPressed: {
                event.accepted = true
                backButton.clicked()
            }
        }

        property real downloadProgress: 0
        property bool imageLoading: false
        property bool editMode: false

        width: 800; height: 480; color: "#d5d6d8"

        ListModel {
            id: photosModel
            ListElement { tag: "Flowers" }
            ListElement { tag: "Wildlife" }
            ListElement { tag: "Prague" }
        }

        DelegateModel { id: albumVisualModel; model: photosModel; delegate: AlbumDelegate {} }

        GridView {
            id: albumView; width: parent.width; height: parent.height; cellWidth: 210; cellHeight: 220
            model: albumVisualModel.parts.album; visible: albumsShade.opacity != 1.0
        }

        Column {
            spacing: 20; anchors { bottom: parent.bottom; right: parent.right; rightMargin: 20; bottomMargin: 20 }
            Button {
                id: newButton; label: qsTr("Add"); rotation: 3
                anchors.horizontalCenter: parent.horizontalCenter
                onClicked: {
                    mainWindow.editMode = false
                    photosModel.append( { tag: "" } )
                    albumView.positionViewAtIndex(albumView.count - 1, GridView.Contain)
                }
            }
            Button {
                id: deleteButton; label: qsTr("Edit"); rotation: -2;
                onClicked: mainWindow.editMode = !mainWindow.editMode
                anchors.horizontalCenter: parent.horizontalCenter
            }
            Button {
                id: quitButton; label: qsTr("Quit"); rotation: -2;
                onClicked: Qt.quit()
                anchors.horizontalCenter: parent.horizontalCenter
            }
        }

        Rectangle {
            id: albumsShade; color: mainWindow.color
            width: parent.width; height: parent.height; opacity: 0.0
        }

        ListView { anchors.fill: parent; model: albumVisualModel.parts.browser; interactive: false }

        Button {
            id: backButton
            label: qsTr("Back")
            rotation: 3
            x: parent.width - backButton.width - 6
            y: -backButton.height - 8
            visible: Qt.platform.os !== "android"
        }

        Rectangle { id: photosShade; color: 'black'; width: parent.width; height: parent.height; opacity: 0; visible: opacity != 0.0 }

        ListView { anchors.fill: parent; model: albumVisualModel.parts.fullscreen; interactive: false }

        Item { id: foreground; anchors.fill: parent }

        ProgressBar {
            progress: mainWindow.downloadProgress; width: parent.width; height: 4
            anchors.bottom: parent.bottom; opacity: mainWindow.imageLoading; visible: opacity != 0.0
        }
    }