import.pro Example File | QtSensors 5.3

- Qt 5.3
- Qt Sensors
- Qt Sensors - Grue Sensor Example
- import.pro Example File
- Qt 5.3.2 Reference Documentation

# import.pro Example File

grue/import/import.pro

    TEMPLATE = lib
    CONFIG += plugin

    TARGET = $$qtLibraryTarget(declarative_grue)
    DESTDIR = ../Grue

    QT = core gui qml sensors

    INCLUDEPATH += $$PWD/../lib
    LIBS += -L$$OUT_PWD/.. -lgruesensor

    # Shared gruesensor library will be installed in parent directory.
    # Define rpath so that this plugin will know where to look for it.
    unix:!mac: QMAKE_LFLAGS += -Wl,-rpath,\\\$\$ORIGIN/..

    SOURCES = main.cpp

    DESTPATH=$$[QT_INSTALL_EXAMPLES]/sensors/grue/Grue

    target.path=$$DESTPATH
    INSTALLS += target

    qmldir.files=$$PWD/qmldir
    qmldir.path=$$DESTPATH
    INSTALLS += qmldir

    OTHER_FILES += \
        plugin.json qmldir

    copyfile = $$PWD/qmldir
    copydest = $$DESTDIR

    # On Windows, use backslashes as directory separators
    equals(QMAKE_HOST.os, Windows) {
        copyfile ~= s,/,\\,g
        copydest ~= s,/,\\,g
    }

    # Copy the qmldir file to the same folder as the plugin binary
    QMAKE_POST_LINK += $$QMAKE_COPY $$quote($$copyfile) $$quote($$copydest) $$escape_expand(\\n\\t)