%language=ANSI-C
%enum
%struct-type
%readonly-tables
%define hash-function-name confitems_hash
%define lookup-function-name confitems_get
%define initializer-suffix ,0,NULL,0,NULL
struct conf_item;
%%
base_dir,             0, ITEM_V(base_dir, env_string, absolute_path)
cache_dir,            1, ITEM(cache_dir, env_string)
cache_dir_levels,     2, ITEM_V(cache_dir_levels, unsigned, dir_levels)
compiler,             3, ITEM(compiler, string)
compiler_check,       4, ITEM(compiler_check, string)
compression,          5, ITEM(compression, bool)
compression_level,    6, ITEM(compression_level, unsigned)
cpp_extension,        7, ITEM(cpp_extension, string)
direct_mode,          8, ITEM(direct_mode, bool)
disable,              9, ITEM(disable, bool)
extra_files_to_hash, 10, ITEM(extra_files_to_hash, env_string)
hard_link,           11, ITEM(hard_link, bool)
hash_dir,            12, ITEM(hash_dir, bool)
log_file,            13, ITEM(log_file, env_string)
max_files,           14, ITEM(max_files, unsigned)
max_size,            15, ITEM(max_size, size)
path,                16, ITEM(path, env_string)
prefix_command,      17, ITEM(prefix_command, env_string)
read_only,           18, ITEM(read_only, bool)
read_only_direct,    19, ITEM(read_only_direct, bool)
recache,             20, ITEM(recache, bool)
run_second_cpp,      21, ITEM(run_second_cpp, bool)
sloppiness,          22, ITEM(sloppiness, sloppiness)
stats,               23, ITEM(stats, bool)
temporary_dir,       24, ITEM(temporary_dir, env_string)
umask,               25, ITEM(umask, umask)
unify,               26, ITEM(unify, bool)
