#!/usr/bin/perl -w
# -*- perl -*-
#
# Plugin to monitor packages that should be installed on systems using
# apt-get (mostly Debian, but also RedHat).
#
# The differences between this plugin and the apt plugins, is that this
# plugin separates each distro with its own plot, and actually draws
# graphs.
#
# This plugin needs a cronjob that runs apt-get update every hour or so
#
# ex 
#
# /etc/cron.d/munin-plugin-apt
# 53 * * * *	root	apt-get update > /dev/null 2>&1
# 23 08 * * * 	root	apt-get update > /dev/null
# 
# Remember to randomize when these cronjobs are run on your servers
#
# Usage: place in /etc/munin/plugins (or link it there using ln -s)
#
# Parameters understood:
#
# 	config   (required)
# 	autoconf (optional - used by munin-config)
#	update <maxinterval> <probability>
#		Updates the APT database randomly, guaranteeing there
#		won't be more than <maxinterval> seconds between each
#		update.  Otherwise, there is a a 1 in <probability>
#		chance that an update will occur.
#
# Magic markers - optional - used by installation scripts and
# munin-config:
#
#%# family=manual
#%# capabilities=autoconf
#
# Now for the real work...

use strict;

$ENV{'LANG'}="C";
$ENV{'LC_ALL'}="C";

my $statefile = "/var/lib/munin/plugin-state/plugin-apt.state";
my $distro=`lsb_release -c 2> /dev/null | cut -f2`;
chomp($distro);
my @releases = ("$distro", "$distro-backports","$distro-proposed", "$distro-updates", "$distro-security");


sub print_state() {
    if(-l $statefile) {
	die("$statefile is a symbolic link, refusing to read it.");
    }
    if (! -e "$statefile") {
	update_state ();
    }
    if (! -e "$statefile") {
	die ("$statefile does not exist. Something wicked happened.");
    }
    open(STATE, "$statefile")
	or die("Couldn't open state file $statefile for reading.");
    print while <STATE>;
    close STATE;
}

sub update_state() {
	if(-l $statefile) {
		die("$statefile is a symbolic link, refusing to touch it.");
	}
	open(STATE, ">$statefile")
		or die("Couldn't open state file $statefile for writing.");
	foreach my $release (@releases) {
	    my $apt="apt-get -u dist-upgrade --print-uris --yes -s 2> /dev/null | grep '^Inst.*/$release)\$' |";
	    open (APT, "$apt") or exit 22;

		my $count = 0;

	    while (<APT>)
	    {
			$count++;
	    }

	    print STATE "pending_$release.value ", $count, "\n";

	}
	close(STATE);
}

sub update_helpandexit() {
	print("apt update <maxinterval> <probability> -- update apt databases randomly\n\n",
	      " maxinterval:\n",
	      "  Enforce the updating of the apt database if it has\n",
	      "  been more than (maxinterval many seconds since the last update.\n\n",
	      " probability:\n",
	      "  There's a 1 in (probability) chance that the database\n",
	      "  will be updated.\n");
	exit(1);
}

if ($ARGV[0] and $ARGV[0] eq "autoconf")
{
	`apt-get -v >/dev/null 2>/dev/null`;
	if ($? eq "0")
	{
		print "yes\n";
		exit 0;
	}
	else
	{
		print "no (apt-get not found)\n";
		exit 1;
	}
}

if ($ARGV[0] and $ARGV[0] eq "config") {

    print "graph_title Pending packages\n";
    print "graph_vlabel Total packages\n";
    print "graph_category system\n";

    foreach my $release (@releases) {
	$release =~ s/-/_/;
	print "pending_$release.label pending_$release\n";
	print "pending_$release.warning 0:0\n";
    }
    exit 0;
}

if ($ARGV[0] and $ARGV[0] eq "update") {
	my $maxinterval = $ARGV[1] ? $ARGV[1] : update_helpandexit;
	my $probability = $ARGV[2] ? $ARGV[2] : update_helpandexit;
	
	# if it's been $probability seconds since the last update, do
	# it now.
	if(-e $statefile &&
	   (stat($statefile))[10] + $maxinterval < time()) {
		update_state();
		exec("/usr/bin/apt-get update")
			or die("Unable to exec() apt-get");
	}

	# if the state-file doesn't exist, create it.
	if(!-e $statefile) {
		update_state();
	}

	# update the database if the 1 in $probability check hits.
	if(!int(rand($probability))) {
		update_state();
		exec("/usr/bin/apt-get update")
			or die("Unable to exec() apt-get");
	}
	exit(0);
}

print_state ();

exit 0;

# vim:syntax=perl
